【原创】windows实用脚本:IP和DNS快速切换批处理脚本

blogdaren 2016-07-11 抢沙发 1446人次

请顺序认真阅读:

【1】.  本脚本可灵活自由定制,脚本附有详细备注说明,若有需要请自行编辑脚本自行配置.

【2】.  复制本文脚本代码,然后粘贴到记事本,最后保存命名为如 dns.bat, 双击执行即可看到你人性化的GUI操作画面,傻瓜向导式操作.

【3】.  脚本代码如下【请完整复制】:

@echo off
rem @desc         IP和DNS快速切换批处理脚本
rem @author      lgh_2002@163.com
rem @website    www.blogdaren.com
title IP和DNS快速切换批处理脚本 


rem 以下几个参数用户请自行配置
set NAME="本地连接"    
set IP=192.168.1.111
set MASK=255.255.255.0    
set GATEWAY=192.168.1.1
set DNS1=192.168.1.250
rem set DNS2=114.114.114.114
rem 以上几个参数用户请自行配置


:start
cls
echo =========================IP和DNS快速切换批处理脚本=============================
echo.
echo    *** 本批处理可以快速切换以及自由定制IP和DNS设置 ***
echo    *** 本脚本很多参数可以定制, 若有需要请用记事本打开本脚本自行修改 ***
echo.
echo    1. 查看本机当前网络配置参数
echo    2. 自动获得IP==自动获得DNS
echo    3. 自动获得IP==手动设置DNS: 如192.168.1.250
echo    4. 手动设置IP==手动设置DNS
echo    5. 退出脚本......
echo    8. 都别管我!!! 我就是想启动一下QQ做个演练......
echo.
echo =========================IP和DNS快速切换批处理脚本=============================
echo.


set /P action=请选择输入命令序号【1-5】:
if /I "%action%"=="1" goto :1
if /I "%action%"=="2" goto :2
if /I "%action%"=="3" goto :3
if /I "%action%"=="4" goto :4
if /I "%action%"=="5" goto :5
if /I "%action%"=="8" goto :8
goto :start


:1
cls
ipconfig /all
echo 按任意键返回主菜单...
pause >nul
goto :start


rem 自动获得IP==自动获得DNS
:2
cls
echo 工作模式:自动获得IP==自动获得DNS
echo 正在从DHCP自动获取IP地址...    
netsh interface ip set address %NAME% dhcp    
echo 正在从DHCP自动获取DNS地址...    
netsh interface ip set dns %NAME% dhcp     
echo 动态DNS设置完成,按任意键查看当前网络信息...
pause > nul
goto :1


rem 自动获得IP==手动设置DNS
:3
cls
echo 工作模式:自动获得IP==手动设置DNS
echo 正在从DHCP自动获取IP地址...    
netsh interface ip set address %NAME% dhcp    
echo 首选DNS = %DNS1%     
netsh interface ipv4 set dns name=%NAME% source=static addr=%DNS1% register=PRIMARY >nul     
rem echo 备用DNS = %DNS2%     
rem netsh interface ipv4 add dns name=%NAME% addr=%DNS2% index=2 >nul     
echo 静态DNS设置完成,按任意键查看当前网络信息...
pause > nul
goto :1


rem 手动设置IP==手动设置DNS
:4
cls
echo 工作模式:手动设置IP==手动设置DNS
echo IP地址 = %IP%    
echo 子网掩码 = %MASK%    
echo 默认网关 = %GATEWAY%    
netsh interface ipv4 set address name=%NAME% source=static addr=%IP% mask=%MASK% gateway=%GATEWAY% gwmetric=0 >nul     
echo 首选DNS = %DNS1%     
netsh interface ipv4 set dns name=%NAME% source=static addr=%DNS1% register=PRIMARY >nul     
rem echo 备用DNS = %DNS2%     
rem netsh interface ipv4 add dns name=%NAME% addr=%DNS2% index=2 >nul     
echo 静态DNS设置完成,按任意键查看当前网络信息...
pause > nul
goto :1

:8
cls
echo "prepare to boot QQ ....."
start "" "C:\Program Files\Tencent\QQ\QQProtect\Bin\QQProtect.exe"
pause > nul
goto :1

:5
exit
 

【4】. 效果图:


11.png


22.png


33.png


44.png

版权声明:除非注明,本文由( blogdaren )原创,转载请保留文章出处。

本文链接:【原创】windows实用脚本:IP和DNS快速切换批处理脚本

发表评论:

您的昵称:
电子邮件:
个人主页: